From 3aaa7ceb2831210ed18d33b89c7f7027202baa6b Mon Sep 17 00:00:00 2001
From: Denis 'GNUtoo' Carikli <GNUtoo@cyberdimension.org>
Date: May 24 2021 18:10:34 +0000
Subject: libre: Add arm-linux-gnueabi-linux-api-headers 4.19


This PKGBUILD is based on the
aarch64-linux-gnu-linux-libre-api-headers PKGBUILD.

It is needed for packaging arm-linux-gnueabi-glibc.

Signed-off-by: Denis 'GNUtoo' Carikli <GNUtoo@cyberdimension.org>

---

diff --git a/libre/arm-linux-gnueabi-linux-api-headers/PKGBUILD b/libre/arm-linux-gnueabi-linux-api-headers/PKGBUILD
new file mode 100644
index 0000000..892f1f5
--- /dev/null
+++ b/libre/arm-linux-gnueabi-linux-api-headers/PKGBUILD
@@ -0,0 +1,37 @@
+# Maintainer (Arch): Anatol Pomozov <anatol.pomozov@gmail.com>
+
+_target_arch=arm
+_target=arm-linux-gnueabi
+pkgname=$_target-linux-libre-api-headers
+_pkgver=4.19-gnu
+
+_srcver=${_pkgver%-*}
+pkgver=${_pkgver//-/_}
+pkgrel=1
+pkgdesc="Kernel headers sanitized for use in userspace ($_target)"
+arch=(any)
+url='https://linux-libre.fsfla.org'
+license=(GPL2)
+provides=("$_target-linux-api-headers=${_srcver}")
+conflicts=("$_target-linux-api-headers")
+replaces=("$_target-linux-api-headers")
+source=("https://linux-libre.fsfla.org/pub/linux-libre/releases/${_pkgver}/linux-libre-${_pkgver}.tar.xz"{,.sign})
+sha512sums=('5bc800b3beff43a8c15bd5515f4e0babe2beb5fa600491b7b37110e22d9b739d293f1e38753ed681be289c51390e0e64b3e60ce0db0a3bfe1f94ee5c014579a3'
+            'SKIP')
+validpgpkeys=('474402C8C582DAFBE389C427BCB7CF877E7D47A7') # Alexandre Oliva
+
+build() {
+  cd linux-$_srcver
+
+  make ARCH=$_target_arch mrproper
+  make ARCH=$_target_arch headers_check
+}
+
+package() {
+  cd linux-$_srcver
+
+  make INSTALL_HDR_PATH="$pkgdir/usr/$_target/" ARCH=$_target_arch V=0 headers_install
+
+  # clean-up unnecessary files generated during install
+  find "$pkgdir" \( -name .install -or -name ..install.cmd \) -delete
+}